NS2 Patch 269 Server Info

Obraxis · September 2014

Hi once again Server Ops!

NS2 Patch 268 had a few things slip by us which we didn't pick up in our weeks of testing. Virtually all of the major issues should be fixed in our next patch 269.

We're hoping this solves almost all major crashing issues with both server and client. We continue to work on stability and performance in the background to help improve NS2 for the long-term.

If your server crashes, please upload a 32bit dump file to your favorite hosting service and email the link to ns2cdt[at]gmail.com - our programmers will look at the dumps and help fix issues for future patches.

Release will be around 10AM PST (San Francisco, USA) / 5PM BST (London, UK) / 3AM (Thursday - Sydney, Australia) TODAY (Wednesday).

We know there was a major issue with mods not working in 268, including ones we said were compatible with 268 last time like NS2+ and Shine. These have both been testing during our playtesting and should have no issues on release. Client-side mods should also now work much better.

Server Mods that have been made compatible with 268 should with with 269, however as per usual, disable any older mods until they have been updated to 269 compatibility to ensure your server's stability.

Changelog will be available soon on the UWE website when the patch gets released, but you can always work it out from our public trello here: https://trello.com/b/91ApENY6/ns2-cdt-development-tracker

Thanks again for continuing to run NS2 servers!

-Obraxis
NS2 CDT Co-Lead

ZEROibis · September 2014

Do not forget to send out an e-mail over the mail list for those admins that are not checking he forums.

Obraxis · September 2014

ZEROibis wrote: »

Do not forget to send out an e-mail over the mail list for those admins that are not checking he forums.

I already did hours ago

https://groups.google.com/forum/?hl=en-GB#!topic/uwe-server-ops/kzO4Q9HpvJs

SupaFred · September 2014

Could you also send an email just after it's released? This way I can update the servers as soon as an update is available.

ZEROibis · September 2014

Obraxis wrote: »

ZEROibis wrote: »

Do not forget to send out an e-mail over the mail list for those admins that are not checking he forums.

I already did hours ago

https://groups.google.com/forum/?hl=en-GB#!topic/uwe-server-ops/kzO4Q9HpvJs

Yep, sorry somehow I missed it. I got to get used to reading e-mail on this new screen I guess lol.

ZEROibis · September 2014

So build delayed?

Obraxis · September 2014

Just waiting on the final 'go' - patch is ready to leave the tubes though.

ATF · September 2014

:!!

ZEROibis · September 2014

Go! Go! Go!, does that help?

Obraxis · September 2014

https://twitter.com/NS2CDT/status/507296539862376448

ZeroEarTh · September 2014

Read this plz CDT , now i cant play with this new update 269

http://forums.unknownworlds.com/discussion/135500/patch-269-help-me-black-screen-after-click-play-cant-do-anything#latest

Kaneh · September 2014

does the server log still overwrite itself on restart?

cause i run firedaemon so it auto-restarts when it crashes so i can never actually pull a log to help with.

is it possible to make it save to different log files?

Obraxis · September 2014

Hi server Ops!

269 went out and somehow during the build-process the version of Tram we finalized didn't make it out, and has some odd Invalid Triangles in the map which were not there in the final 269 build we tested.

We've re-published the 269 patch to steam which has fixed the issue. You will need to update your servers again and tram should be fixed. All clients should have already had the update.

Sorry for any inconvenience!

-Obraxis

ATF · September 2014

I keep reading that server ops are asking how to save the log since it gets overwritten. While the way it handles the log is a shameful piece of code, it's relatively easy to keep a log archive.

Below is a simple batch script that will start / restart your server while copying timestamped logs into the specified folder. It runs independantly from your server, meaning nothing will break if you start / exit the script while your server is running. It can also perform automatic restarts if the server exceeds a specified memory usage.

Here's how to use it:
- Paste the script into a file and name it restartscript.cmd (make sure file extensions aren't hidden on your system)
- Create a .lnk file with the server.exe as the target and add the command line options
- Open the .cmd (with notepad++ for example) and edit the variables to your liking.

@ECHO off
::
:: DO NOT edit this file while the script is running!
::
SET serverpath=C:\Users\Obraxis\Desktop& REM Path of the .lnk to server.exe, which carries the commandline attributes
SET serverlnk=Startns2server.lnk& REM Name of the .lnk (avoid spaces)
SET serverexe=server.exe 
SET monitoringdelay=30& REM Check every n seconds if server.exe is an existing process. 
                         REM Can be no more than 59 sec for the daily leakcheck to work.
SET logarchivepath=D:\ns2ds-log-archive\& REM Path to archive log before starting/restarting.
SET dailyrestartenabled=true& REM Define whether you want the script to check for memleaks and restart if necessary.
SET dailyrestartat=10:30& REM Time of day to check for memleaks.
SET memleakthreshold=1750000& REM If server.exe uses more than n kbytes of memory, force a restart.
:: Variables below this line should not be modified.
SET initialserverstart=true
title NS2DS Restartscript 
ECHO Settings: %monitoringdelay%s interval, leakcheck at %dailyrestartat%am, threshold at %memleakthreshold%kbyte.
ECHO[ 
:BATCHSTART
TASKLIST /nh /fi "imagename eq %serverexe%" | FIND /i "%serverexe%" > NUL && (
  ECHO %date% %time% NS2DS found, starting monitoring.
  SET initialserverstart=false
  GOTO STATUSCHECK
  ) || ( GOTO COPYLOG  
  )
:CONTINUEINIT
TIMEOUT 15
START /D "%serverpath%" %serverlnk% 2> NUL && (
  ECHO %date% %time% Initial start. Logging: %logging%
  ) || (
  ECHO %date% %time% Cannot start NS2DS. Exiting. Logging: %logging% 
  GOTO ENDROUTINE
  )
ECHO[
SET initialserverstart=false
TIMEOUT %monitoringdelay% > NUL
GOTO STATUSCHECK

:STATUSCHECK
TASKLIST /nh /fi "imagename eq %serverexe%" | FIND /i "%serverexe%" > NUL && (
  rem
  ) || GOTO STARTSERVER
IF %dailyrestartenabled%==true TIME /t | FIND /i "%dailyrestartat%" > NUL && (
  GOTO DAILYRESTART
  )
TIMEOUT %monitoringdelay% > NUL
GOTO STATUSCHECK

:STARTSERVER
GOTO COPYLOG
:CONTINUESTART
START /D "%serverpath%" %serverlnk% 2> NUL && (
  ECHO %date% %time% NS2DS restarted. Logging: %logging%
  ) || (
  ECHO %date% %time% Cannot restart NS2DS. Exiting. Logging: %logging%
  GOTO ENDROUTINE
  )
TIMEOUT %monitoringdelay% > NUL
GOTO STATUSCHECK

:DAILYRESTART
TASKLIST /fi "memusage GT %memleakthreshold%" | FIND /i "server.exe" > NUL && (
  ECHO %date% %time% NS2DS leaks above threshold. Terminating.
  TASKKILL /IM %serverexe%
  ) || ( 
  TIMEOUT 60 /NOBREAK > NUL
  GOTO STATUSCHECK
  )
TIMEOUT 8 /NOBREAK > NUL 
TASKLIST /nh /fi "imagename eq %serverexe%" | FIND /i "%serverexe%" > NUL && (
  ECHO %date% %time% NS2DS unresponsive. Killing process.
  TASKKILL /F /IM %serverexe%
  TIMEOUT 15 /NOBREAK > NUL
  ) 
TASKLIST /nh /fi "imagename eq %serverexe%" | FIND /i "%serverexe%" > NUL && (
  ECHO %date% %time% Cannot kill process. Exiting.
  GOTO ENDROUTINE 
  )
TIMEOUT 60 /NOBREAK > NUL
GOTO STATUSCHECK

:COPYLOG
FOR /F "tokens=1,2,3 delims=." %%x IN ("%date%") DO SET LogDate=%%z%%y%%x
FOR /F "tokens=1,2 delims=:," %%v IN ("%time%") DO SET LogTime=%%v%%w
COPY /Y "%appdata%\Natural Selection 2\log-Server.txt" "%logarchivepath%%Logdate%-%LogTime%.txt" >NUL && ( SET logging=OK 
  ) || SET logging=FAILED!
IF %initialserverstart%==true GOTO CONTINUEINIT
IF %initialserverstart%==false GOTO CONTINUESTART



:ENDROUTINE
TIMEOUT /T -1 /NOBREAK > NUL
:: prevents closing of window in case something goes wrong

>-

NS2 Patch 269 Server Info

Comments